thomas
e16829f19a
automated update of zen browser appimage version and hash ## changelog from `1.19.2a` to `1.19.2b` upstream release: https://github.com/zen-browser/desktop/releases/tag/1.19.2b # Zen Stable Release ## Security [Various security fixes](https://www.mozilla.org/en-US/security/advisories/mfsa2026-19/) ## New Features - Updated to Firefox 148.0.2 ## Fixes - Fixed some RSS live folders not working with certain feeds. ([#12685](https://github.com/zen-browser/desktop/issues/12685)) - Improved performance for spaces, specially when switching between them. ([#11851](https://github.com/zen-browser/desktop/issues/11851)) - Other minor bug fixes and improvements. Co-authored-by: gitea actions <actions@localhost> Reviewed-on: https://gitea.unrail.xyz/thomas/nixos-config/pulls/11
42 lines
1.3 KiB
Nix
42 lines
1.3 KiB
Nix
{lib, ...}: {
|
|
perSystem = {pkgs, ...}: let
|
|
pname = "zen-browser";
|
|
version = "1.19.2b";
|
|
|
|
src = pkgs.fetchurl {
|
|
url = "https://github.com/zen-browser/desktop/releases/download/${version}/zen-x86_64.AppImage";
|
|
hash = "sha256-lDn7rIYDgmyUnc3PdIASXfpXBXASL6TEdzyZfT716cI=";
|
|
};
|
|
|
|
appimageContents = pkgs.appimageTools.extract {inherit pname version src;};
|
|
in {
|
|
packages.zen-browser = pkgs.appimageTools.wrapType2 {
|
|
inherit pname version src;
|
|
|
|
extraPkgs = pkgs: [pkgs.ffmpeg-full];
|
|
|
|
extraInstallCommands = ''
|
|
desktop_file=$(find ${appimageContents} -name "*.desktop" | head -n1)
|
|
if [ -n "$desktop_file" ]; then
|
|
install -m 444 -D "$desktop_file" "$out/share/applications/${pname}.desktop"
|
|
substituteInPlace "$out/share/applications/${pname}.desktop" \
|
|
--replace 'Exec=zen' 'Exec=${pname}'
|
|
fi
|
|
|
|
if [ -d ${appimageContents}/usr/share/icons ]; then
|
|
cp -r ${appimageContents}/usr/share/icons $out/share
|
|
fi
|
|
|
|
ln -s $out/bin/${pname} $out/bin/zen
|
|
'';
|
|
|
|
meta = {
|
|
description = "Experience tranquillity while browsing the web without people tracking you!";
|
|
homepage = "https://zen-browser.app";
|
|
license = lib.licenses.mpl20;
|
|
platforms = ["x86_64-linux"];
|
|
};
|
|
};
|
|
};
|
|
}
|